Bu dersimizde A.S 2.0'da buton yapmasını öğreneceğiz.

İlk olarak Library üzerinde "New Font" diyerek "Tahoma" fontunu seçin. Fontun "identifier" seçeneğini aktifleştirin ve tanımlayıcı ismine "Tahoma" yazın.



Daha sonra sahnemizin birinci karesinde kod bölümüne (Kısayol:F9) aşağıdaki kodu yapıştırın.

//filtreler ithal ediliyor.
import flash.filters.GlowFilter;
var labelGlow:GlowFilter = new GlowFilter(0xFFFFFF, .30, 4, 4, 3, 3);
var labelFilters:Array = [labelGlow];
import flash.filters.DropShadowFilter;
var buttonShadow:DropShadowFilter = new DropShadowFilter(1, 45, 0x000000, 1, 4, 4, 1, 3);
var buttonFilters:Array = [buttonShadow];
//butonun içinde bulunacağı yeni bir movie clip oluşturuluyor ve sahneye yerleştiriliyor.
this.createEmptyMovieClip("myButton1", this.getNextHighestDepth());
myButton1._x = 200;
myButton1._y = 100;
//gradient dolgu parametreleri
var fillType:String = "linear";
var colors:Array = [0xFAD4DB, 0xEC748B, 0xC13A59, 0xA81230];
var alphas:Array = [100, 100, 100, 100];
var ratios:Array = [0, 126, 127, 255];
var matrix:Object = {matrixType:"box", x:0, y:0, w:120, h:30, r:90/180*Math.PI};
//butonun arka planı oluşturuluyor.
myButton1.createEmptyMovieClip("buttonBkg", myButton1.getNextHighestDepth());
//buton arka plan dolguları oluşturuluyor.
myButton1.buttonBkg.lineStyle(0, 0x000000, 60, true, "none", "square", "round");
myButton1.buttonBkg.beginGradientFill(fillType, colors, alphas, ratios, matrix);
myButton1.buttonBkg.lineTo(120, 0);
myButton1.buttonBkg.lineTo(120, 30);
myButton1.buttonBkg.lineTo(0, 30);
myButton1.buttonBkg.lineTo(0, 0);
myButton1.buttonBkg.endFill();
//text format objesi oluşturuluyor.
var myFormat:TextFormat = new TextFormat();
myFormat.align = "center";
myFormat.font = "Tahoma";
myFormat.size = 13;
myFormat.color = 0xFFFFFF;
//Butonun etiketi olacak metin alanı oluşturuluyor.
myButton1.createTextField("labelText", myButton1.getNextHighestDepth(), 0, 5, myButton1._width, 24);
//buton etiketi için çeşitli seçenekler.
myButton1.labelText.text = "sanalkurs.net";
myButton1.labelText.embedFonts = true;
myButton1.labelText.selectable = false;
myButton1.labelText.antiAliasType = "advanced";
myButton1.labelText.setTextFormat(myFormat);
//Buton etiketine filtreler uygulanıyor.
myButton1.labelText.filters = labelFilters;
//Butonu tıklanabilir yapıp bir bağlantı oluşturuyoruz.
myButton1.onRelease = function() {
   getURL("http://www.sanalkurs.net");
}
//Filtreler grafik için butona uygulanıyor. 
myButton1.filters = buttonFilters;

Sonuç: